|
Página 1 de 1
|
Problemas Para Acceder A Un Array De Tableview
| Autor |
Mensaje |
 Ricardo Prieto 
Ricardo Prieto
Programador
Registrado: Septiembre 2015
Mensajes: 109
Edad: 47 Ubicación:  ARGENTINA
|
 Problemas Para Acceder A Un Array De Tableview
Hola tengo problemas para acceder a un array de tableview para crearlos no hay problemas pero el problema surge cunando necesito acceder a ellos.
Agradeceria su ayuda
Public Sub CargarProductos()
Dim Col, R As Integer
NvTablaVenta.Rows.Count = NvTablaVenta.Rows.Count + 1
R = NvTablaVenta.Rows.Max - 1
NvTablaVenta[R, 6].Clear
NvTablaVenta[R, 5].Clear
NvTablaVenta[R, 0].Text = lCodInt
NvTablaVenta[R, 0].Alignment = 3
NvTablaVenta[R, 3].Text = sProducto
NvTablaVenta[R, 3].Alignment = 1
fPrecioFinal = CorregirDecimales(fPrecioFinal)
NvTablaVenta[R, 4].Text = Format(Round(fPrecioFinal, -2), "##.#0")
NvTablaVenta[R, 4].Alignment = 2
SubTotales()
End
Este es una parte del codigo
|
#1 Martes, 08 Diciembre 2015, 03:57 |
|
 |
Shell
Analista Programador
Registrado: Marzo 2010
Mensajes: 5278
Edad: 53 Ubicación:  Al otro lado de la pantalla
|
Re: Problemas Para Acceder A Un Array De Tableview
Hola Ricardo.
¿ Qué error te aparece ?. ¿ Qué ves exactamente ?.
¿ Cómo es la forma de acceder a la tabla ?.
Este es un ejemplo de añadir registros manualmente con un botón.
La variable filas es global.
Existen dos cajas de textos de donde se lee la información y se pasa a la tabla.
Luego se elimina el contenido de las cajas de textos y por ultimo toma el foco una de estas cajas de texto.
Public Sub btnAnadir_Click()
Tabla.Rows.Count = filas + 1
Tabla[filas, 0].Text = txtCampo1.Text
Tabla[filas, 1].Text = txtCampo2.Text
filas += 1
txtCampo1.Text = ""
txtCampo2.Text = ""
txtCampo1.SetFocus()
End
Siempre intenta crear pequeños ejemplos para que puedas entenderlo con más facilidad y luego usa eso
en tu aplicación principal. Divide y vencerás.
Saludos
=================== Gambas Básico
"No es un bug, es una característica no documentada"
|
#2 Martes, 08 Diciembre 2015, 10:27 |
|
|
Ricardo Prieto
Ricardo Prieto
Programador
Registrado: Septiembre 2015
Mensajes: 109
Edad: 47 Ubicación: ARGENTINA
|
Re: Problemas Para Acceder A Un Array De Tableview
Mi problema es que yo cree un array del control TableView y cuando creo una nueva pestaña de un control tabstrip me crea una nuva tabla. El problema es poder acceder a ellas independientemente.
Te paso un codigo para que lo comprendas
'Este codigo Crea la tabla y lo inserta en cada pestaña del tabstrip que se crea...
Public Sub ClonarTabla()
TabStripVentas[TabStripVentas.Index].Caption = "Venata N° " & CStr(TabStripVentas.Count - 1)
TabStripVentas.Index = TabStripVentas.Count - 1
'TabStripVentas[TabStripVentas.Count - 1].Text = CStr(TabStripVentas.Count - 1)
With NvTablaVenta = New TableView(TabStripVentas) As "NvTablaVenta"
.X = 0 '40
.Y = 21 ' 100
.W = 980 'TabVenta.w '200
.H = 497 'TabVenta.h '200
.Columns.Count = 7
.Rows.Count = 1
.Header = 3
.Columns.Count = 7
.Columns[0].Text = "Cod. Art."
.Columns[0].Width = 80
.Columns[1].Text = "Unidades"
.Columns[1].Width = 80
.Columns[2].Text = "Kilos"
.Columns[2].Width = 80
.Columns[3].Text = "Descripción"
.Columns[3].Width = 350
.Columns[4].Text = "Precio"
.Columns[4].Width = 75
.Columns[5].Text = "Descuneto"
.Columns[5].Width = 75
.Columns[6].Text = "Importe"
.Columns[6].Width = 80
.Mode = Select.Multiple
End With
'TabStripVentas.Count += 1
'TabStripVentas.Count -= 1
End
'Esta es una subrutina donde se insertan los datos que necesito en es tabla. Pero solo me inserta en la ultima que cree..
Public Sub CargarProductos()
Dim Col, R, i As Integer
NvTablaVenta.Rows.Count = NvTablaVenta.Rows.Count + 1
R = NvTablaVenta.Rows.Max - 1
NvTablaVenta[R, 6].Clear
NvTablaVenta[R, 5].Clear
NvTablaVenta[R, 0].Text = lCodInt
NvTablaVenta[R, 0].Alignment = 3
NvTablaVenta[R, 3].Text = sProducto
NvTablaVenta[R, 3].Alignment = 1
fPrecioFinal = CorregirDecimales(fPrecioFinal)
NvTablaVenta[R, 4].Text = Format(Round(fPrecioFinal, -2), "##.#0")
NvTablaVenta[R, 4].Alignment = 2
SubTotales()
End
Agredeceria si me pueden ayudar con esto..
|
#3 Martes, 08 Diciembre 2015, 12:14 |
|
|
Shell
Analista Programador
Registrado: Marzo 2010
Mensajes: 5278
Edad: 53 Ubicación: Al otro lado de la pantalla
|
Re: Problemas Para Acceder A Un Array De Tableview
Prueba a ver que hace esto.
Llama a CargarProductos() al final de la creación de la tabla.
Quiere decir, que cada vez que creas una tabla vas a ejecutar el miso proceso "CargarProductos()" en la tabla que ha creado.
Entonces en cada creación de una nueva pestaña, te hará siempre esas operaciones.
- Crear Pestaña.
- Crear Tabla
- CargarProductos
No te preocupes si los compañeros no contestan rápidamente. Llevamos unos días de fiesta en España, día de la Constitución, día de la Inmaculada.
Y lo están aprovechando bien. 
A ver que te parece mi idea de arriba.
Saludos
=================== Gambas Básico
"No es un bug, es una característica no documentada"
última edición por Shell el Martes, 08 Diciembre 2015, 13:48; editado 1 vez |
#4 Martes, 08 Diciembre 2015, 13:47 |
|
|
vuott
Analista Programador
Registrado: Agosto 2013
Mensajes: 2086
Edad: 60 Ubicación: 
|
Re: Problemas Para Acceder A Un Array De Tableview
No se si yo he entiendido bien lo que tu quieres... (será un problema de mi traducción), pero me parece que tu quieres acceder a las propiedades de la TableView puesta en la pestaña que tu eliges.
Pues los objetos, puestos en una pestaña de una TableStrip, son " children" de la TableStrip, y - mejor dicho - en particular de la pestaña donde ellos son puestos, tu tienes que especificar el hijo ( children) de la TabStrip que está en la pestaña que tu eliges.
Por ejemplo queremos acceder a la propiedad .Text de una celda de la TableView puesta en la tercera pestaña (indice 2):
Public Sub Button2_Click()
Dim tw As TableView
' Si solo hay 1 TableView en la pestaña de indice 2, ella será el primero hijo (indice 0):
tw = TabStripVentas[2].Children[0]
' Vamos a poner un caracter en la propiedad ".Text" dela celda [1, 0] de la TableView, puesta en la pestaña de indice 2 de la TableStrip:
tw[1, 0].Text = "a"
End
última edición por vuott el Martes, 08 Diciembre 2015, 18:23; editado 4 veces |
#5 Martes, 08 Diciembre 2015, 18:08 |
|
|
Ricardo Prieto
Ricardo Prieto
Programador
Registrado: Septiembre 2015
Mensajes: 109
Edad: 47 Ubicación: ARGENTINA
|
Re: Problemas Para Acceder A Un Array De Tableview
Gracias Ahora si me cargan los productos que tengo en ontra tabla y me las pasa al tabla que esta en el TabStrip que tengo levantado.. Muchas Gracias
Public Sub CargarProductos()
Dim Col, R, i As Integer
NvTablaVenta = TabStripVentas[TabStripVentas.Index].Children[0] ''---> Perfecto con esta correccion que me pasate funciona perfectamente
NvTablaVenta.Rows.Count = NvTablaVenta.Rows.Count + 1
R = NvTablaVenta.Rows.Max - 1
NvTablaVenta[R, 6].Clear
NvTablaVenta[R, 5].Clear
NvTablaVenta[R, 0].Text = lCodInt
NvTablaVenta[R, 0].Alignment = 3
NvTablaVenta[R, 3].Text = sProducto
NvTablaVenta[R, 3].Alignment = 1
fPrecioFinal = CorregirDecimales(fPrecioFinal)
NvTablaVenta[R, 4].Text = Format(Round(fPrecioFinal, -2), "##.#0")
NvTablaVenta[R, 4].Alignment = 2
SubTotales()
End
|
#6 Miercoles, 09 Diciembre 2015, 01:05 |
|
|
|
|
 Temas parecidos
 Temas parecidos
|
|
Página 1 de 1
|
Usuarios navegando en este tema: 0 registrados, 0 ocultos y 1 invitado
Usuarios registrados conectados: Ninguno
|
No puede crear mensajes
No puede responder temas
No puede editar sus mensajes
No puede borrar sus mensajes
No puede votar en encuestas
No puede adjuntar archivos
Puede descargar archivos
No puede publicar eventos en el calendario
|
|
|
|
|
