https://foro.gambas-es.org/viewtopic.php?f=1&t=8008
-----------------------------------
Shell
Miercoles, 29 Abril 2020, 10:24

Pseint.Argumentos Con Tipos En La Lista De Parámetros.
-----------------------------------
Buenas!.

No sé si habéis usado lo suficiente está aplicación.  En PSeint existen los subprocesos y las funciones.
Según como tengas configurada las opciones del lenguaje será más sencillo o más similar al lenguaje humano a la
forma en que escribamos el código.

Hay una forma, que no tienes que definir los tipos: El modo flexible.
Y hay otro modo que es el estricto. Que es lo más parecido a un lenguaje de programación.

Modo flexible:
[quote]
// este es el ejemplo más simple de esta ayuda, 
// toma dos numeros, los suma y muestra el resultado

Algoritmo Suma


    // para cargar un dato, se le muestra un mensaje al usuario
    // con la instrucción Escribir, y luego se lee el dato en 
    // una variable (A para el primero, B para el segundo) con 
    // la instrucción Leer

    Escribir "Ingrese el primer numero:"
    Leer A

    Escribir "Ingrese el segundo numero:"
    Leer B


    // ahora se calcula la suma y se guarda el resultado en la
    // variable C mediante la asignación (<-)
    
    C <- A+B


    // finalmente, se muestra el resultado, precedido de un 
    // mensaje para avisar al usuario, todo en una sola
    // instrucción Escribir
    
    Escribir "El resultado es: ",C

FinAlgoritmo
[/quote]

Modo estricto:

[quote]
// este es el ejemplo más simple de esta ayuda, 
// toma dos numeros, los suma y muestra el resultado

Proceso Suma

    Definir A,B,C como Reales;

    // para cargar un dato, se le muestra un mensaje al usuario
    // con la instrucción Escribir, y luego se lee el dato en 
    // una variable (A para el primero, B para el segundo) con 
    // la instrucción Leer

    Escribir "Ingrese el primer numero:";
    Leer A;

    Escribir "Ingrese el segundo numero:";
    Leer B;


    // ahora se calcula la suma y se guarda el resultado en la
    // variable C mediante la asignación (<-)
    
    C <- A+B;


    // finalmente, se muestra el resultado, precedido de un 
    // mensaje para avisar al usuario, todo en una sola
    // instrucción Escribir
    
    Escribir "El resultado es: ",C;

FinProceso
[/quote]

Usando funciones. Modo flexible:
[quote]
// funcion que no recibe ni devuelve nada
Funcion Saludar
	Escribir "Hola mundo!"
FinFuncion

// funcion que recibe un argumento por valor, y devuelve su doble
Funcion res <- CalcularDoble(num) 
	res <- num*2 // retorna el doble
FinFuncion

// funcion que recibe un argumento por referencia, y lo modifica
Funcion Triplicar(num por referencia) 
	num <- num*3 // modifica la variable duplicando su valor
FinFuncion

// proceso principal, que invoca a las funciones antes declaradas
Algoritmo PruebaFunciones
	
	
	Escribir "Llamada a la funcion Saludar:"
	Saludar // como no recibe argumentos pueden omitirse los paréntesis vacios
	
	Escribir "Ingrese un valor numérico para x:"
	Leer x
	
	Escribir "Llamada a la función CalcularDoble (pasaje por valor)"
	Escribir "El doble de ",x," es ", CalcularDoble(x)
	Escribir "El valor original de x es ",x
	
	Escribir "Llamada a la función Triplicar (pasaje por referencia)"
	Triplicar(x)
	Escribir "El nuevo valor de x es ", x
	
FinAlgoritmo
[/quote]

Funciones y subprocesos. Modo estricto:

[quote]
// funcion que no recibe ni devuelve nada
SubProceso Saludar
	Escribir "Hola mundo!";
FinSubProceso

// funcion que recibe un argumento por valor, y devuelve su doble
SubProceso res <- CalcularDoble(num) 
	Definir res como real;
	res <- num*2; // retorna el doble
FinSubProceso

// funcion que recibe un argumento por referencia, y lo modifica
SubProceso Triplicar(num por referencia) 
	num <- num*3; // modifica la variable duplicando su valor
FinSubProceso

// proceso principal, que invoca a las funciones antes declaradas
Proceso PruebaFunciones
	
	Definir x Como Real;
	
	Escribir "Llamada a la funcion Saludar:";
	Saludar; // como no recibe argumentos pueden omitirse los paréntesis vacios
	
	Escribir "Ingrese un valor numérico para x:";
	Leer x;
	
	Escribir "Llamada a la función CalcularDoble (pasaje por valor)";
	Escribir "El doble de ",x," es ", CalcularDoble(x);
	Escribir "El valor original de x es ",x;
	
	Escribir "Llamada a la función Triplicar (pasaje por referencia)";
	Triplicar(x);
	Escribir "El nuevo valor de x es ", x;
	
FinProceso

[/quote]

A pesar de todo las opciones de configuración se pueden personalizar:
Os muestro las opciones de configuración usando el modo flexible:

 [img]https://foro.gambas-es.org/files/images/768/opcionesdellenguaje.png[/img]

Tiene una forma "peculiar" de retornar el valor en una función.
[quote]
SubProceso prom <- Promedio ( arreglo, cantidad )
....
Definir prom como Real;
[/quote]

Dentro del mismo cuerpo de la función define el tipo de valor que devolverá la función o subproceso.
Como veis  arreglo y cantidad no se definen los tipos. Pero "a lo mejor"..desde donde se llama se le puede decir 
el tipo.

Si se define en la rutina que llama a la función:
[quote]
Definir x Como Real;
[/quote]

Y luego se llama a la función:

[quote]
Escribir "El doble de ",x," es ", CalcularDoble(x);
[/quote]

Puede que lo entienda.

Estuve haciendo el reto de "El restaurante" en esta aplicación, podemos ver que en Gambas,
tenemos dos tipos distintos en la lista de argumentos de la función.

[code linenumbers=false syntax=gambas]
Public Function numdeplatos(docenasdehuevo As Integer, kilosdechorizo As Float) As Integer
  
  
  
End
[/code]

Hice el ejemplo de las dos formas. Al exportarlo a distintos lenguajes, Java, Python. el tipo usado para las docenas de huevos en vez de ser del tipo entero, 
me lo cambió a real.

En Java..

[code linenumbers=false syntax=java]
public static int numdeplatosv1(double docenasdehuevo, double kilosdechorizo)
[/code]

En Python. Siiii, nunca había visto definir un tipo en Python!. (que raro se ve)  
Aunque no lo hace en la lista de argumentos, dentro del cuerpo de la función, si que lo hace
y el interprete lo da por valido... :shock: 

[code linenumbers=false syntax=python]
def numdeplatosv2(docenasdehuevo, kilosdechorizo):
	platos = int()
.....
[/code]

Probaré a definir y a llamar a la función con ese tipo a ver que hace.

Saludos


