https://foro.gambas-es.org/viewtopic.php?f=5&t=5113&p=29869#p29869
-----------------------------------
vuott
Lunes, 25 Enero 2016, 00:26

Re: Panel Movil Luminoso De Leds
-----------------------------------
[quote user="Mr_Electronico" post="29868"]no consigo poner el Refresh correctamente en el timer.[/quote]
Yo digo algo parecido a este ejemplo:
[code linenumbers=false syntax=gambas]Private tempus As Timer
Private DrawingArea1 As DrawingArea
Private svg As SvgImage
Private i As Integer
Private Const ruta As String = "/usr/share/icons/hicolor/scalable/categories"


Public Sub Form_Open()

' Carga el primero archivo imagen svg contenido en la ruta elegida:
  svg = SvgImage.Load(ruta &/ Dir(ruta, Null, gb.File)[0])

' Crea la DrawingArea:
  With DrawingArea1 = New DrawingArea(Me) As "DrawingArea1"
    .X = 100
    .Y = 100
    .W = svg.W
    .H = svg.H
  End With

' Crea el objeto Timer, ponendo tambien un delay de ms 300:
  With tempus = New Timer As "Tempus"
    .Delay = 300
    .Start()
  End With

End


Public Sub Tempus_Timer()   ' Cada ms 300 se levanta este evento

  Dim s As String

' Incrementa esta variable para identificar el siguiente archivo imagen .svg contenido en la ruta elegida: 
   Inc i

' Si el valor de la variable "i" es = a la cantidad -1 de los archivos imagen .svg contenidos en la nuestra ruta, para el Timer:
   If i = Dir(ruta, Null, gb.File).Max Then tempus.Stop
    
' Carga el nombre del archivo imagen sgv en la variable "s":
   s = Dir(ruta, Null, gb.File)[i]
    
' Carga el nuevo archivo imagen svg:
   svg = SvgImage.Load(ruta &/ s)
    
' Refresca la DrawingArea:
   DrawingArea1.Refresh()
  
End


Public Sub DrawingArea1_Draw()   ' Este evento se levanta tambien cada vez la DrawingArea se refresca

' Dibuja en la DrawingArea el nuevo archivo imagen svg cargado con el metodo "SvgImage.Load()":
   svg.Paint

End[/code]



[quote user="Mr_Electronico" post="29868"]Pero de momento me da errores y no lo he conseguido...[/quote]
Que errores te da ?


