https://foro.gambas-es.org/viewtopic.php?f=3&t=779&p=4337#p4337
-----------------------------------
techm3
Martes, 20 Julio 2010, 23:24

Re: Buscar En Una Base De Datos
-----------------------------------
La verdad es que estoy comenzando con esto de base de datos y me ayudaría una pequeña explicación con un ejemplo ejecutable y no es para sacar provecho, es solo que no entiendo muy bien lo que quieres decir. Este es el código del formulario en donde quiero usar TxtSearch como el buscador y que los resultados se muestren en tabla(ColumnView)(es usado para mostrar todos los datos de la base al abrir el formulario)
[code linenumbers=false syntax=gambas]' Gambas class file
  PRIVATE hConn AS Connection
  
  PRIVATE FUNCTION ConectarBase() AS Boolean
  
    IF hConn <> NULL THEN RETURN FALSE
    
    hConn = NEW Connection
    
    hConn.Host = "localhost"
    hConn.Name = "amp"
    hConn.Type = "MySQL"
    hConn.login = "root"
    hConn.Password = "password"
    TRY hConn.OPEN()
    IF ERROR THEN 
      hConn = NULL
      Message.Error("Error al conectar con la base")
      RETURN TRUE
    ENDIF 
    
      RETURN FALSE

END

PUBLIC SUB CerrarConexion()
  
  IF hConn = NULL THEN RETURN 
  hConn.CLOSE()
  hConn = NULL
  
END

PUBLIC SUB Form_Open()

  DIM hResul AS Result
  DIM Clave AS String
  
  tabla.Clear()
  
  IF ConectarBase() THEN RETURN 
  
  tabla.Columns.Count = 5
  tabla.Columns[0].text = "Title"
  tabla.Columns[1].text = "Classification"
  tabla.Columns[2].Text = "Concentration"
  tabla.Columns[3].Text = "Format"
  tabla.Columns[4].text = "Comments"
  
  hResul = hConn.Exec("select * from movinfo")
  
  DO WHILE hResul.Available
  
    Clave = hResul["title"]
    
    tabla.Add(Clave, Clave)
    
    tabla[Clave][1] = hResul["classification"]
    tabla[Clave][2] = hResul["concentration"]
    tabla[Clave][3] = hResul["format"]
    tabla[Clave][4] = hResul["comments"]
  
    hResul.MoveNext()
    
  LOOP 
  CerrarConexion()
  
  ME.Title = "Video Database"

END

PUBLIC SUB tabla_KeyRelease()
  
  IF Key.Code = Key.Delete THEN 
    
    IF tabla.Current = NULL THEN RETURN 
    IF tabla.Current.Selected = FALSE THEN RETURN 
    
    IF ConectarBase() THEN RETURN 
    
    TRY hConn.Exec("delete from movinfo where title=&1", tabla.Current.Key)
    IF ERROR THEN 
      Message.Error("Can't erase \n" & ERROR .text)
    ELSE 
    tabla.Current.Delete()
    ENDIF 
    
    CerrarConexion()
  ENDIF 
  
END

PUBLIC SUB BtnAdd_Click()

  IF ConectarBase() THEN RETURN 
  FData.RunNew(hConn)
  CerrarConexion()
Form_Open()

END

PUBLIC SUB tabla_Activate()
  
  DIM hResul AS Result
  
  IF tabla.Current = NULL THEN RETURN 
  
  IF ConectarBase() THEN RETURN 
  
  hResul = hConn.Edit("movinfo", "title=&1", tabla.Current.Key)
  FData.RunEdit(hResul)
  
  tabla.Current[0] = hResul["title"]
  tabla.Current[1] = hResul["classification"]
  tabla.Current[2] = hResul["concentration"]
  tabla.Current[3] = hResul["format"]
  tabla.Current[4] = hResul["comments"]
  
  CerrarConexion()
  
END[/code]


