Este asunto no explicará cómo construir con el codigo "por sí solo", "artesanalmente" un array de tipo String[ ], ya que un Objeto, teniendo sus recursos (Propiedades, Métodos y Eventos), posee una organización interna muy compleja.
Este explicará cómo construir "artesanalmente" la sola parte del área de memoria, donde están guardados los datos del tipo que gambas llama "String", y la manera de usarla.
En general (tomemos como lenguaje de referencia el C) una variable, que se refiere a una "cadena", contiene una dirección (la prima celda) del área de memoria donde están guardados los datos. Cada valor que atañe a una dirección de memoria ocupa una cantidad de byte (celdas) de memoria
cantidad_ocupada = SizeOf(gb.Pointer)
Por lo tanto, un array de cadenas es claramente un área de memoria contenente una o más direcciones de memoria, que totalmente ocupa una cantidad de memoria:
cantidad_ocupada = SizeOf(gb.Pointer) * número_de_direcciones
Hagamos un ejemplo practico: vamos a construir un simple array de tipo String[ ] contenente 3 elementos.
El su área de memoria tendrà 3 valores, que ocupan SizeOf(gb.Pointer) * 3 y rapresentan las direcciones de memoria de cada cadena de caracteres, como sigue:
| d | i | r | e | cc | i | ó | n || d | i | r | e | cc | i | ó | n || d | i | r | e | cc | i | ó | n || = 24 byte/celdas ocupados
Vamos a construir en gambas este área de memoria:
Public Sub Main()
Dim arr As Pointer
Dim i As Integer
Dim s As String
' Tenemos que reservar una cantidad de memoria para los 3 valores que identifican las 3 direcciones de memoria de las 3 cadenas:
arr = Alloc(SizeOf(gb.Pointer), 3)
' Vamnos a ver el resultado:
For i = 0 To (SizeOf(gb.Pointer) * 3) - 1
If i Mod SizeOf(gb.Pointer) == 0 Then
s = "------------ Byte/celda donde iniciarà el valor de la dirección de memoria de la cadena\n"
Endif
Write i & " " & Hex(Byte@(arr + i), 2) & s
s = "\n"
Next
' Nunc memoriam liberat !
Free(arr)
' Además, para más garantías, podemos dirle tambien que la variable de tipo Puntero apunte a la celda num. 0 de la memoria:
arr = 0
End
Dim arr As Pointer
Dim i As Integer
Dim s As String
' Tenemos que reservar una cantidad de memoria para los 3 valores que identifican las 3 direcciones de memoria de las 3 cadenas:
arr = Alloc(SizeOf(gb.Pointer), 3)
' Vamnos a ver el resultado:
For i = 0 To (SizeOf(gb.Pointer) * 3) - 1
If i Mod SizeOf(gb.Pointer) == 0 Then
s = "------------ Byte/celda donde iniciarà el valor de la dirección de memoria de la cadena\n"
Endif
Write i & " " & Hex(Byte@(arr + i), 2) & s
s = "\n"
Next
' Nunc memoriam liberat !
Free(arr)
' Además, para más garantías, podemos dirle tambien que la variable de tipo Puntero apunte a la celda num. 0 de la memoria:
arr = 0
End
Ahora podemos crear las tres cadenas de carácteres que tenemos, después, que guardar en el área de memoria de nuestro simple array.
Public Sub Main()
Dim arr, s0, s1, s2, pen As Pointer
Dim i As Integer
Dim s As String
Dim st As Stream
' Tenemos que reservar una cantidad de memoria para los 3 valores que identifican las 3 direcciones de memoria de las 3 cadenas:
arr = Alloc(SizeOf(gb.Pointer), 3)
' Aquí los tres cadenas de carácteres que tenemos que guardar en el área de memoria de nuestro simple array.
' Podríamos usar 3 variables de tipo "String", pero por motivos didácticos utilizaremos 3 variables de tipo "Pointer".
s0 = Alloc("Primera")
s1 = Alloc("Segunda")
s2 = Alloc("Tercera")
' Ahora vamos a escribir - con los recursos de "Memory Stream" - las 3 direcciones de memoria de los 3 Punteros en el área de memoria de nuestro simple array.
' Porque usamos "Memory Stream" ?
' Porque en gambas para escribir (si queremos guardar mediante recursos nativos de gambas) datos en un área de memoria,
' apuntado por un Puntero, solo podemos utilizar los recursos de "Memory Stream".
st = Memory arr For Write
Write #st, s0 As Pointer
Write #st, s1 As Pointer
Write #st, s2 As Pointer
st.Close
' Vamos a ver la disposición de los valores que atañan a las direcciones de memoria de los 3 Punteros en el área de memoria de nuestro array:
For i = 0 To (SizeOf(gb.Pointer) * 3) - 1
If i Mod SizeOf(gb.Pointer) == 0 Then
s = "------------ Inicio valor dirección de memoria de la cadena\n"
Endif
Write i & " " & Hex(Byte@(arr + i), 2) & s
s = "\n"
Next
Print
' Vamos a ver los resultados:
For i = 0 To 2
' Penetremos en el área de memoria de nuestro array deslizando por su byte (celdas):
pen = Pointer@(arr + (i * SizeOf(gb.Pointer)))
' Penetremos en el área de memoria de cada cadena de carácteres dereferenciando el Puntero:
Print "cadena #"; i, String@(pen)
Next
' Nunc memoriam liberat !
Free(s0)
Free(s1)
Free(s2)
Free(arr)
' Además, para más garantías, podemos dirle tambien que la variable de tipo Puntero apunte a la celda num. 0 de la memoria:
arr = 0
End
Dim arr, s0, s1, s2, pen As Pointer
Dim i As Integer
Dim s As String
Dim st As Stream
' Tenemos que reservar una cantidad de memoria para los 3 valores que identifican las 3 direcciones de memoria de las 3 cadenas:
arr = Alloc(SizeOf(gb.Pointer), 3)
' Aquí los tres cadenas de carácteres que tenemos que guardar en el área de memoria de nuestro simple array.
' Podríamos usar 3 variables de tipo "String", pero por motivos didácticos utilizaremos 3 variables de tipo "Pointer".
s0 = Alloc("Primera")
s1 = Alloc("Segunda")
s2 = Alloc("Tercera")
' Ahora vamos a escribir - con los recursos de "Memory Stream" - las 3 direcciones de memoria de los 3 Punteros en el área de memoria de nuestro simple array.
' Porque usamos "Memory Stream" ?
' Porque en gambas para escribir (si queremos guardar mediante recursos nativos de gambas) datos en un área de memoria,
' apuntado por un Puntero, solo podemos utilizar los recursos de "Memory Stream".
st = Memory arr For Write
Write #st, s0 As Pointer
Write #st, s1 As Pointer
Write #st, s2 As Pointer
st.Close
' Vamos a ver la disposición de los valores que atañan a las direcciones de memoria de los 3 Punteros en el área de memoria de nuestro array:
For i = 0 To (SizeOf(gb.Pointer) * 3) - 1
If i Mod SizeOf(gb.Pointer) == 0 Then
s = "------------ Inicio valor dirección de memoria de la cadena\n"
Endif
Write i & " " & Hex(Byte@(arr + i), 2) & s
s = "\n"
Next
' Vamos a ver los resultados:
For i = 0 To 2
' Penetremos en el área de memoria de nuestro array deslizando por su byte (celdas):
pen = Pointer@(arr + (i * SizeOf(gb.Pointer)))
' Penetremos en el área de memoria de cada cadena de carácteres dereferenciando el Puntero:
Print "cadena #"; i, String@(pen)
Next
' Nunc memoriam liberat !
Free(s0)
Free(s1)
Free(s2)
Free(arr)
' Además, para más garantías, podemos dirle tambien que la variable de tipo Puntero apunte a la celda num. 0 de la memoria:
arr = 0
End